Multiple Multiplexer und Tests auf dem Breadboard – MIDI-Controller E18

Gleich mehrere 4051 Multiplexer lassen sich an einen Arduino anschließen. Auf dem Weg zu unserem eigenen selbst gebauten MIDI Controller gucken wir uns an wie das geht. Außerdem testen wir unsere Schaltung bevor wir alles zusammenlöten.

int controlChange = 176; // Control-Change auf MIDI Kanal 1

int potiWert[16];
int controllerWert[16];
int controllerWertAlt[16];

int i = 0;

int bit1 = 0;
int bit2 = 0;
int bit3 = 0;


void setup() {
 //Select-Pins 4051s
 pinMode(2, OUTPUT);
 pinMode(3, OUTPUT);
 pinMode(4, OUTPUT);
 
 Serial.begin(9600);
}


void loop() {
 for (i = 0; i <= 7; i++) {
 bit1 = bitRead(i,0);
 bit2 = bitRead(i,1);
 bit3 = bitRead(i,2);
 
 digitalWrite(2, bit1);
 digitalWrite(3, bit2);
 digitalWrite(4, bit3);
 
 potisAbfragen(i,A0);
 potisAbfragen(i+8,A1);
 }
}


void potisAbfragen(int zaehler, int analogPin) {
 potiWert[zaehler] = 0.2 * potiWert[zaehler] + 0.8 * analogRead(analogPin);
 controllerWert[zaehler] = map(potiWert[zaehler],0,1023,0,127);
 if (controllerWert[zaehler] != controllerWertAlt[zaehler]) {
 sendeMIDI(controlChange, (20+zaehler), controllerWert[zaehler]);
 controllerWertAlt[zaehler] = controllerWert[zaehler];
 }
}


void sendeMIDI(int statusByte, int dataByte1, int dataByte2) {
 Serial.write(statusByte);
 Serial.write(dataByte1);
 Serial.write(dataByte2);
}